Microsoft Office Web Components (OWC) são componentes da própria Microsoft que controlam publicações de planilhas, gráficos, e bancos de dados para a Web. Podem também ser utilizados para visualizar esses tipos de documentos, quando esses estão disponíveis na web, como páginas de internet.
Se você tem Microsoft FrontPage, Microsoft Access, e Microsoft Excel instalado, o Office Web Components lhe permitirá a interação dos mesmos com páginas Web. Na versão 4.01 ou posterior do Internet Explorer, com o Office Web Components você poderá visualizar os documentos (planilhas, gráficos, ou bancos de dados) numa página Web. Já na versão 5 ou superior, você poderá visualizar data access pages*.
Se você não tem o Office instalado em seu micro, O Office Web Components terá a funcionalidade de somente-leitura para documentos do Office.
Nota: Se você não tem uma licença do Office, o OWC terá somente a funcionalidade de somente-leitura, e não poderá interagir com os documentos ("Data access pages" são a exceção pois não requerem uma licença de Office).
* Data Access Pages são páginas Web em HTML especiais, que são vinculadas diretamente a um banco de dados através de um engine de banco de dados. As páginas residem no ambiente Access ou são exportadas para o Microsoft Internet Information Server (IIS) e, então, publicadas ou vistas com o browser Internet Explorer.
Com o componente Office Web Components você pode gerar gráficos em formato GIF dinamicamente. Segue abaixo dois exemplos de gráficos: em colunas e em formato pizza.
Gráfico em Colunas
<--Início barras.asp--> (não copie essa linha)
<%
Set oChart = CreateObject("OWC10.ChartSpace")
Set c = oChart.Constants
oChart.Border.Color = c.chColorNone
Dim categories(3), Vals(3), Vals2(3)
' críe um array que represente os valores da primeira série.
Vals(0) = 20
Vals(1) = 40
Vals(2) = 30
Vals(3) = 10
' críe um array que represente os valores da segunda série.
Vals2(0) = 35
Vals2(1) = 35
Vals2(2) = 25
Vals2(3) = 5
' gráfico de coluna com as duas séries e quatro categorias.
' críe um array que represente as categorias, as categorias serão as mesmas para as duas séries.
categories(0) = "Zona Norte"
categories(1) = "Zona Sul"
categories(2) = "Zona Oeste"
categories(3) = "Zona Leste"
With oChart
' adicionando um objeto do gráfico.
.Charts.Add
' adicionando o tipo do gráfico.
.Charts(0).Type = oChart.Constants.chChartTypeColumn3d
' adicionando a primeira série ao gráfico.
.Charts(0).SeriesCollection.Add
' ajustando o subtítulo da série (o texto da legenda).
.Charts(0).SeriesCollection(0).Caption = "Faturamento por Região - Setembro"
' adicionando as categorias e os valores da primeira série.
.Charts(0).SeriesCollection(0).SetData c.chDimCategories, c.chDataLiteral, categories
.Charts(0).SeriesCollection(0).SetData c.chDimValues, c.chDataLiteral, Vals
End With
' adicionando a segunda série ao gráfico, legenda, categorias e valores.
With oChart
.Charts(0).SeriesCollection.Add
.Charts(0).SeriesCollection(1).Caption = "Faturamento por Região - Agosto"
.Charts(0).SeriesCollection(1).SetData c.chDimCategories, c.chDataLiteral, Categories
.Charts(0).SeriesCollection(1).SetData c.chDimValues, c.chDataLiteral, Vals2
.Charts(0).HasLegend = True
.Charts(0).HasTitle = True
End With
Response.Expires = 0
Response.Buffer = true
Response.Clear
Response.ContentType = "image/gif"
'ajustando o tamanho do gráfico (figura).
Response.BinaryWrite oChart.GetPicture("gif",750, 400)
%>
<--Fim barras.asp--> (não copie essa linha)
Gráfico em Formato Pizza
<--Início pizza.asp--> (não copie essa linha)
<%
Set oChart = CreateObject("OWC10.ChartSpace")
Set c = oChart.Constants
oChart.Border.Color = c.chColorNone
Dim categories(3), Vals(3), Vals2(3)
' críe um array que represente os valores da série.
Vals(0) = 20
Vals(1) = 40
Vals(2) = 30
Vals(3) = 10
' gráfico de pizza com quatro categorias.
' críe um array que represente as categorias.
categories(0) = "Zona Norte"
categories(1) = "Zona Sul"
categories(2) = "Zona Oeste"
categories(3) = "Zona Leste"
With oChart
' adicionando um objeto do gráfico.
.Charts.Add
' adicionando o tipo do gráfico.
.Charts(0).Type = oChart.Constants.chChartTypePie3d
' adicionando a série ao gráfico.
.Charts(0).SeriesCollection.Add
' ajustando o subtítulo da série (o texto da legenda).
.Charts(0).SeriesCollection(0).Caption = "Faturamento por Região"
' adicionando as categorias e os valoresda série.
.Charts(0).SeriesCollection(0).SetData c.chDimCategories, c.chDataLiteral, categories
.Charts(0).SeriesCollection(0).SetData c.chDimValues, c.chDataLiteral, Vals
.Charts(0).HasLegend = True
.Charts(0).HasTitle = True
End With
Response.Expires = 0
Response.Buffer = true
Response.Clear
Response.ContentType = "image/gif"
'ajustando o tamanho do gráfico (figura).
Response.BinaryWrite oChart.GetPicture("gif",400, 400)
%>
<--Fim pizza.asp--> (não copie essa linha)
Observação: Ao final do script, é necessário atribuir o valor "Nothing" para os objetos criados. Para o exemplo acima ficaria assim:
<% Set objPieChart = Nothing %>
Para mais informarções sobre o componente Office Web Components, acesse o site da Microsoft: http://msdn.microsoft.com/library
|
